Encrypts or decrypts an array of Bytes in one step using a specified mode.
Public Declare Function DES_BytesMode Lib "diCryptoSys.dll"
(ByRef abOutput As Byte, ByRef abData As Byte, ByVal nDataLen As Long,
ByRef abKey As Byte, ByVal bEncrypt As Boolean,
ByVal strMode As String, ByRef abInitV As Byte) As Long
nRet = DES_BytesMode(abOutput(0), abData(0), nDataLen,
abKey(0), bEncrypt, strMode, abInitV(0))
Byte array of sufficient length to receive the output.Byte array containing the input data.Long equal to length of the input data in bytes.Byte array containing the key.Boolean direction flag:
set as True to encrypt or False
to decrypt.String specifying the confidentiality mode:Byte containing the
initialization vector (IV), or zero (0) for ECB mode.
long _stdcall DES_BytesMode(unsigned char *output, const unsigned char *input,
long nbytes, const unsigned char *key,
int bEncrypt, const char *lpszMode, const unsigned char *iv);
Long: If successful, the return value is 0;
otherwise it returns a non-zero error code.
Des.Encrypt Method (Byte[], Byte[], Mode, Byte[])
Des.Decrypt Method (Byte[], Byte[], Mode, Byte[])
The input data abData must be an exact multiple of 8 bytes long. If not, an error code will be returned. The key abKey must be exactly 8 bytes long. The output array abOutput must be at least nDataLen bytes long. abOutput and abData may be the same.
VB6/VBA users: Note the '(0)' after the byte array variables.
Dim nRet As Long
Dim strOutput As String
Dim strInput As String
Dim strKey As String
Dim strHexIV As String
Dim sCorrect As String
Dim nDataLen As Long
Dim abKey() As Byte
Dim abOutput() As Byte
Dim abData() As Byte
Dim abInitV() As Byte
strKey = "0123456789abcdef"
strHexIV = "1234567890abcdef"
strInput = "Now is the time for all "
sCorrect = "e5c7cdde872bf27c43e934008c389c0f683788499a7c05f6"
' Convert to byte arrays and compute lengths
abKey = cnvBytesFromHexStr(strKey)
abInitV = cnvBytesFromHexStr(strHexIV)
abData = StrConv(strInput, vbFromUnicode)
nDataLen = Len(strInput)
' Dimension array for output
ReDim abOutput(nDataLen - 1)
Debug.Print "KY="; cnvHexStrFromBytes(abKey)
Debug.Print "IV="; cnvHexStrFromBytes(abInitV)
Debug.Print "PT="; cnvHexStrFromBytes(abData)
' Encrypt in one-off process
nRet = DES_BytesMode(abOutput(0), abData(0), nDataLen, _
abKey(0), True, "CBC", abInitV(0))
Debug.Print "CT="; cnvHexStrFromBytes(abOutput), nRet
Debug.Print "OK="; sCorrect
Debug.Assert (sCorrect = cnvHexStrFromBytes(abOutput))
' Now decrypt back
nRet = DES_BytesMode(abData(0), abOutput(0), nDataLen, _
abKey(0), DECRYPT, "CBC", abInitV(0))
strOutput = StrConv(abData(), vbUnicode)
Debug.Print "P'="; "["; strOutput; "]"
Debug.Assert (strOutput = strInput)
This should result in output as follows:
KY=0123456789ABCDEF IV=1234567890ABCDEF PT=4E6F77206973207468652074696D6520666F7220616C6C20 CT=E5C7CDDE872BF27C43E934008C389C0F683788499A7C05F6 0 OK=e5c7cdde872bf27c43e934008c389c0f683788499a7c05f6 P'=[Now is the time for all ]